2A3A1-AMPCD.ino

Go to the documentation of this file.

/**************************************************************************************
 *        ____                   _    _                       _
 *       / __ \                 | |  | |                     | |
 *      | |  | |_ __   ___ _ __ | |__| | ___  _ __ _ __   ___| |_
 *      | |  | | '_ \ / _ \ '_ \|  __  |/ _ \| '__| '_ \ / _ \ __|
 *      | |__| | |_) |  __/ | | | |  | | (_) | |  | | | |  __/ |_
 *       \____/| .__/ \___|_| |_|_|  |_|\___/|_|  |_| |_|\___|\__|
 *             | |
 *             |_|
 *   ----------------------------------------------------------------------------------
 *   Copyright 2016-2024 OpenHornet
 *
 *   Licensed under the Apache License, Version 2.0 (the "License");
 *   you may not use this file except in compliance with the License.
 *   You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 *   Unless required by applicable law or agreed to in writing, software
 *   distributed under the License is distributed on an "AS IS" BASIS,
 *   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 *   See the License for the specific language governing permissions and
 *   limitations under the License.
 *   ----------------------------------------------------------------------------------
 *   Note: All other portions of OpenHornet not within the 'OpenHornet-Software' 
 *   GitHub repository is released under the Creative Commons Attribution -
 *   Non-Commercial - Share Alike License. (CC BY-NC-SA 4.0)
 *   ----------------------------------------------------------------------------------
 *   This Project uses Doxygen as a documentation generator.
 *   Please use Doxygen capable comments.
 **************************************************************************************/
 
#if defined(__AVR_ATmega328P__) || defined(__AVR_ATmega2560__)
#define DCSBIOS_IRQ_SERIAL  
#else
#define DCSBIOS_DEFAULT_SERIAL  
#endif
 
#ifdef __AVR__
#include <avr/power.h>
#endif
 
 
#define TXENABLE_PIN 5  
#define UART1_SELECT    
 
#include "DcsBios.h"
#include "Wire.h"
#include "TCA9534.h"
 
// Define pins per the OH Interconnect.
#define AMPCD_ROT_A A0       
#define AMPCD_ROT_OFF A1     
#define HDG_P 8              
#define HDG_M 10             
#define CRS_P 4              
#define CRS_M 7              
#define AMPCD_BACK_LIGHT 9  
#define AMPCD_IRQ 6 
 
TCA9534 ampcdButtons[4] = {
  TCA9534(0x23),  //Left Row
  TCA9534(0x20),  //Top Row
  TCA9534(0x22),  // Right Row
  TCA9534(0x21)
};  // Bottom Row
 
// Setup global variables for reading DDI button presses.
bool lastBtnState[28];               
bool buttonState[28];                
uint8_t inputRegister[4];            
unsigned long lastDebounceTime[28];  
unsigned long debounceDelay = 10;    
 
int index;
 
char *AMPCD_Btns[] = { "AMPCD_GAIN_SW",
                       "AMPCD_NIGHT_DAY",
                       "AMPCD_SYM_SW",
                       "AMPCD_CONT_SW" };
char btnName[20];
 
//Connect switches to DCS-BIOS
DcsBios::Potentiometer ampcdBrtCtl("AMPCD_BRT_CTL", AMPCD_ROT_A);
DcsBios::Switch3Pos leftDdiCrsSw("LEFT_DDI_CRS_SW", CRS_P, CRS_M);
DcsBios::Switch3Pos leftDdiHdgSw("LEFT_DDI_HDG_SW", HDG_P, HDG_M);
 
void onInstrIntLtChange(unsigned int newValue) {
  analogWrite(AMPCD_BACK_LIGHT, map(newValue, 0, 65535, 0, 255));
}
DcsBios::IntegerBuffer instrIntLtBuffer(FA_18C_hornet_INSTR_INT_LT, onInstrIntLtChange);
 
void setup() {
 
  // Run DCS Bios setup function
  DcsBios::setup();
 
  pinMode(AMPCD_IRQ, OUTPUT);
 
  pinMode(AMPCD_BACK_LIGHT, OUTPUT); // set backlight pinmode to output
  analogWrite(AMPCD_BACK_LIGHT, 0); // turn-off backlighting
  for (int i = 0; i < sizeof(lastBtnState) / sizeof(lastBtnState[0]); i++) {
    lastBtnState[i] = 0;
  }
 
  for (int i = 0; i < sizeof(ampcdButtons) / sizeof(ampcdButtons[0]); i++) {
    ampcdButtons[i].Begin();
    for (int j = 0; j < 7; j++) {
      ampcdButtons[i].PinMode(j, INPUT);
    }
  }
}
 
void loop() {
 
  //Run DCS Bios loop function
  DcsBios::loop();
 
  for (int i = 0; i < sizeof(ampcdButtons) / sizeof(ampcdButtons[0]); i++) {
    inputRegister[i] = ampcdButtons[i].ReadAll();
 
    for (int j = 0; j < 7; j++) {
 
      index = j + (7 * i);
 
      bool btnState = (inputRegister[i] >> (6 - j)) & 1;
 
      if (btnState != lastBtnState[index]) {
        lastDebounceTime[index] = millis();
      }
 
      if ((millis() - lastDebounceTime[index]) > debounceDelay) {
        if (btnState != buttonState[index]) {
          buttonState[index] = btnState;
          if (j > 4) {            // one of the AMPCD NIGHT, GAIN, SYMBOLOGY, CONTRAST rockers.
            if (btnState != 1) {  // If one of the AMPCD rocker buttons determine if value to send to DCS 0 or 2.
              if (i == 0 or i == 1) {
                if (j == 5) { DcsBios::sendDcsBiosMessage(AMPCD_Btns[i], "2"); }
                if (j == 6) { DcsBios::sendDcsBiosMessage(AMPCD_Btns[i], "0"); }
              } else {
                if (j == 5) { DcsBios::sendDcsBiosMessage(AMPCD_Btns[i], "0"); }
                if (j == 6) { DcsBios::sendDcsBiosMessage(AMPCD_Btns[i], "2"); }
              }
            } else {  // every AMPCD button has a "1" state.
              DcsBios::sendDcsBiosMessage(AMPCD_Btns[i], "1");
            }
          } else {  // One of the 20 push buttons.
            int btnNum = 4 - j + 5 * i;
            sprintf(btnName, "AMPCD_PB_%02d", btnNum + 1);
            DcsBios::sendDcsBiosMessage(btnName, btnState == 1 ? "0" : "1");
          }
        }
      }
      lastBtnState[index] = btnState;
    }
  }
}